nekochemist
fe0aa07f3c
deleted: .config/apps-list.md modified: .config/btop/btop.conf deleted: .config/config.kdl new file: .config/fish/completions/fisher.fish new file: .config/fish/completions/fzf_configure_bindings.fish new file: .config/fish/conf.d/fzf.fish new file: .config/fish/fish_plugins modified: .config/fish/fish_variables new file: .config/fish/functions/_fzf_configure_bindings_help.fish new file: .config/fish/functions/_fzf_extract_var_info.fish new file: .config/fish/functions/_fzf_preview_changed_file.fish new file: .config/fish/functions/_fzf_preview_file.fish new file: .config/fish/functions/_fzf_report_diff_type.fish new file: .config/fish/functions/_fzf_report_file_type.fish new file: .config/fish/functions/_fzf_search_directory.fish new file: .config/fish/functions/_fzf_search_git_log.fish new file: .config/fish/functions/_fzf_search_git_status.fish new file: .config/fish/functions/_fzf_search_history.fish new file: .config/fish/functions/_fzf_search_processes.fish new file: .config/fish/functions/_fzf_search_variables.fish new file: .config/fish/functions/_fzf_wrapper.fish new file: .config/fish/functions/fisher.fish new file: .config/fish/functions/fzf_configure_bindings.fish new file: .config/fish/functions/y.fish new file: .config/fish/functions/yz.fish new file: ".config/fish/functions/\320\275\321\217.fish" modified: .config/kitty/kitty.conf modified: .config/niri/config.kdl modified: .config/nvim/lazy-lock.json new file: .config/nvim/lua/plugins/luasnip.lua new file: .config/nvim/lua/plugins/markview.lua new file: .config/nvim/lua/plugins/marp-nvim.lua new file: .config/nvim/lua/plugins/nvim-snippy.lua new file: .config/nvim/lua/plugins/render-markdown.lua deleted: .config/nwg-look/config deleted: .config/zathura/zathurarc modified: apps-list.md new file: background renamed: .config/mimeapps.list -> mimeapps.list renamed: .config/pavucontrol.ini -> pavucontrol.ini deleted: sing-box-03.json renamed: .config/user-dirs.dirs -> user-dirs.dirs renamed: .config/user-dirs.locale -> user-dirs.locale
41 lines
1.8 KiB
Fish
41 lines
1.8 KiB
Fish
function _fzf_search_git_status --description "Search the output of git status. Replace the current token with the selected file paths."
|
|
if not git rev-parse --git-dir >/dev/null 2>&1
|
|
echo '_fzf_search_git_status: Not in a git repository.' >&2
|
|
else
|
|
set -f preview_cmd '_fzf_preview_changed_file {}'
|
|
if set --query fzf_diff_highlighter
|
|
set preview_cmd "$preview_cmd | $fzf_diff_highlighter"
|
|
end
|
|
|
|
set -f selected_paths (
|
|
# Pass configuration color.status=always to force status to use colors even though output is sent to a pipe
|
|
git -c color.status=always status --short |
|
|
_fzf_wrapper --ansi \
|
|
--multi \
|
|
--prompt="Git Status> " \
|
|
--query=(commandline --current-token) \
|
|
--preview=$preview_cmd \
|
|
--nth="2.." \
|
|
$fzf_git_status_opts
|
|
)
|
|
if test $status -eq 0
|
|
# git status --short automatically escapes the paths of most files for us so not going to bother trying to handle
|
|
# the few edges cases of weird file names that should be extremely rare (e.g. "this;needs;escaping")
|
|
set -f cleaned_paths
|
|
|
|
for path in $selected_paths
|
|
if test (string sub --length 1 $path) = R
|
|
# path has been renamed and looks like "R LICENSE -> LICENSE.md"
|
|
# extract the path to use from after the arrow
|
|
set --append cleaned_paths (string split -- "-> " $path)[-1]
|
|
else
|
|
set --append cleaned_paths (string sub --start=4 $path)
|
|
end
|
|
end
|
|
|
|
commandline --current-token --replace -- (string join ' ' $cleaned_paths)
|
|
end
|
|
end
|
|
|
|
commandline --function repaint
|
|
end
|